Slimber/Cocoa/CocoaMenulet.mm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

#include "Slimber/Cocoa/CocoaMenulet.h"

using namespace Swift;

CocoaMenulet::CocoaMenulet() {
	menu = [[NSMenu alloc] init];

	statusItem = [[[NSStatusBar systemStatusBar] 
			statusItemWithLength: NSVariableStatusItemLength] retain];
	[statusItem setHighlightMode: YES];
	[statusItem setEnabled: YES];
	[statusItem setToolTip: @"Slimber"];	
	[statusItem setMenu: menu];
}

CocoaMenulet::~CocoaMenulet() {
	[statusItem release];
	[menu release];
}

void CocoaMenulet::setIcon(const String& icon) {
	NSString* path = [[NSBundle mainBundle] pathForResource: 
			[NSString stringWithUTF8String: icon.getUTF8Data()] ofType:@"png"];
	NSImage* image = [[NSImage alloc] initWithContentsOfFile: path];
	[statusItem setImage: image];
	[image release];
}

void CocoaMenulet::clear() {
	while ([menu numberOfItems] > 0) {
		[menu removeItemAtIndex: 0];
	}
}

void CocoaMenulet::addItem(const Swift::String& name, const String& icon) {
	NSMenuItem* item = [[NSMenuItem alloc] initWithTitle: 
		[NSString stringWithUTF8String: name.getUTF8Data()]
		action: NULL keyEquivalent: @""];
	if (!icon.isEmpty()) {
		NSString* path = [[NSBundle mainBundle] pathForResource: 
				[NSString stringWithUTF8String: icon.getUTF8Data()] ofType:@"png"];
		NSImage* image = [[NSImage alloc] initWithContentsOfFile: path];
		[item setImage: [[NSImage alloc] initWithContentsOfFile: path]];
		[image release];
	}
	[menu addItem: item];
	[item release];
}

void CocoaMenulet::addAboutItem() {
	NSMenuItem* item = [[NSMenuItem alloc] initWithTitle: @"About Slimber" action: @selector(orderFrontStandardAboutPanel:) keyEquivalent: @""];
	[item setTarget: [NSApplication sharedApplication]];
	[menu addItem: item];
	[item release];
}

void CocoaMenulet::addExitItem() {
	NSMenuItem* item = [[NSMenuItem alloc] initWithTitle: @"Exit" action: @selector(terminate:) keyEquivalent: @""];
	[item setTarget: [NSApplication sharedApplication]];
	[menu addItem: item];
	[item release];
}

void CocoaMenulet::addSeparator() {
	[menu addItem: [NSMenuItem separatorItem]];
}