Swift/QtUI/CocoaApplicationActivateHelper.mm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

/*
 * Copyright (c) 2012-2016 Isode Limited.
 * All rights reserved.
 * See the COPYING file for more information.
 */

#include <Swift/QtUI/CocoaApplicationActivateHelper.h>

#include <memory>

#include <boost/function.hpp>

#include <QApplication>

#include <Cocoa/Cocoa.h>

@interface CocoaApplicationActivateHelperDelegate : NSObject {
}
- (void) handleActivate: (NSAppleEventDescriptor*) event withReply: (NSAppleEventDescriptor*) reply;
@end

@implementation CocoaApplicationActivateHelperDelegate
- (void) handleActivate: (NSAppleEventDescriptor*) event withReply: (NSAppleEventDescriptor*) reply {
    (void) event; (void) reply;
    QApplication::postEvent(qApp, new QEvent(QEvent::ApplicationActivate));
}
@end

namespace Swift {

struct CocoaApplicationActivateHelper::Private {
    CocoaApplicationActivateHelperDelegate* delegate;
    bool initialized;
};

CocoaApplicationActivateHelper::CocoaApplicationActivateHelper() : p(new Private()) {
    p->delegate = [[CocoaApplicationActivateHelperDelegate alloc] init];
    p->initialized = false;
    qApp->installEventFilter(this);
}

CocoaApplicationActivateHelper::~CocoaApplicationActivateHelper() {
    [[NSAppleEventManager sharedAppleEventManager] removeEventHandlerForEventClass:kCoreEventClass andEventID:kAEReopenApplication];
    [p->delegate release];
}

bool CocoaApplicationActivateHelper::eventFilter(QObject* object, QEvent* event) {
    if (object == qApp && event->type() == QEvent::ApplicationActivate && !p->initialized) {
        [[NSAppleEventManager sharedAppleEventManager] setEventHandler:p->delegate andSelector:@selector(handleActivate:withReply:) forEventClass:kCoreEventClass andEventID:kAEReopenApplication];
        p->initialized = true;
    }
    return QObject::eventFilter(object, event);
}


}