summaryrefslogtreecommitdiffstats
blob: 3400e54ba33085fdf292cf0bb0435116ef6049e4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Import("env")

################################################################################
# Flags
################################################################################

if env["SCONS_STAGE"] == "flags" :
	env["SWIFTOOLS_FLAGS"] = {
			"LIBPATH": [Dir(".")],
			"LIBS": ["SwifTools"]
		}

################################################################################
# Build
################################################################################

if env["SCONS_STAGE"] == "build" :
	myenv = env.Clone()
	myenv.MergeFlags(myenv["BOOST_FLAGS"])

	sources = [
			"Idle/IdleDetector.cpp",
			"Idle/ActualIdleDetector.cpp",
			"Idle/IdleQuerier.cpp",
			"Idle/PlatformIdleQuerier.cpp",
			"AutoUpdater/AutoUpdater.cpp",
			"AutoUpdater/PlatformAutoUpdaterFactory.cpp",
			"Linkify.cpp",
		]

	if myenv.get("HAVE_SPARKLE", 0) :
		myenv.MergeFlags(myenv["SPARKLE_FLAGS"])
		myenv.Append(CPPDEFINES = ["HAVE_SPARKLE"])
		sources += ["AutoUpdater/SparkleAutoUpdater.mm"]

	if myenv["PLATFORM"] == "win32" :
		sources += ["Idle/WindowsIdleQuerier.cpp"]
	elif myenv["PLATFORM"] == "darwin" :
		sources += ["Idle/MacOSXIdleQuerier.cpp"]
	elif myenv["HAVE_XSS"] :
		myenv.Append(CPPDEFINES = ["HAVE_XSS"])
		sources += ["Idle/XSSIdleQuerier.cpp"]
	else :
		sources += ["Idle/DummyIdleQuerier.cpp"]

	myenv.StaticLibrary("SwifTools", sources)

	SConscript(dirs = [
			"Idle/IdleQuerierTest",
			"Idle/UnitTest",
			"UnitTest"
		])